project(rtlsdr)

set(rtlsdr_SOURCES
    rtlsdrinput.cpp
    rtlsdrplugin.cpp
    rtlsdrsettings.cpp
    rtlsdrwebapiadapter.cpp
    rtlsdrthread.cpp
)

set(rtlsdr_HEADERS
    rtlsdrinput.h
    rtlsdrplugin.h
    rtlsdrsettings.h
    rtlsdrwebapiadapter.h
    rtlsdrthread.h
)
include_directories(
    ${CMAKE_SOURCE_DIR}/swagger/sdrangel/code/qt5/client
    ${LIBRTLSDR_INCLUDE_DIR}
)

if(NOT SERVER_MODE)
    set(rtlsdr_SOURCES
        ${rtlsdr_SOURCES}
        rtlsdrgui.cpp

        rtlsdrgui.ui
    )
    set(rtlsdr_HEADERS
        ${rtlsdr_HEADERS}
        rtlsdrgui.h
    )

    set(TARGET_NAME ${PLUGINS_PREFIX}inputrtlsdr)
    set(TARGET_LIB "Qt::Widgets")
    set(TARGET_LIB_GUI "sdrgui")
    set(INSTALL_FOLDER ${INSTALL_PLUGINS_DIR})
else()
    set(TARGET_NAME ${PLUGINSSRV_PREFIX}inputrtlsdrsrv)
    set(TARGET_LIB "")
    set(TARGET_LIB_GUI "")
    set(INSTALL_FOLDER ${INSTALL_PLUGINSSRV_DIR})
endif()

if(NOT Qt6_FOUND)
    add_library(${TARGET_NAME} ${rtlsdr_SOURCES})
else()
    qt_add_plugin(${TARGET_NAME} CLASS_NAME RTLSDRPlugin ${rtlsdr_SOURCES})
endif()

if(NOT BUILD_SHARED_LIBS)
    set_property(GLOBAL APPEND PROPERTY STATIC_PLUGINS_PROPERTY ${TARGET_NAME})
endif()

if(LIBUSB_DEPENDS)
    add_dependencies(${TARGET_NAME} ${LIBUSB_DEPENDS})
endif()

target_link_libraries(${TARGET_NAME} PRIVATE
        Qt::Core
        ${TARGET_LIB}
	sdrbase
	${TARGET_LIB_GUI}
        swagger
        ${LIBRTLSDR_LIBRARIES}
        ${LIBUSB_LIBRARIES}
)

install(TARGETS ${TARGET_NAME} DESTINATION ${INSTALL_FOLDER})

# Install debug symbols
if (WIN32)
    install(FILES $<TARGET_PDB_FILE:${TARGET_NAME}> CONFIGURATIONS Debug RelWithDebInfo DESTINATION ${INSTALL_FOLDER} )
endif()