project(sdrplay)

set(sdrplay_SOURCES
    sdrplayinput.cpp
    sdrplayplugin.cpp
    sdrplaysettings.cpp
    sdrplaywebapiadapter.cpp
    sdrplaythread.cpp
)

set(sdrplay_HEADERS
    sdrplayinput.h
    sdrplayplugin.h
    sdrplaysettings.h
    sdrplaywebapiadapter.h
    sdrplaythread.h
)

include_directories(
    ${CMAKE_SOURCE_DIR}/swagger/sdrangel/code/qt5/client
    ${LIBMIRISDR_INCLUDE_DIR}
)

if(NOT SERVER_MODE)
    set(sdrplay_SOURCES
        ${sdrplay_SOURCES}
        sdrplaygui.cpp

        sdrplaygui.ui
    )
    set(sdrplay_HEADERS
        ${sdrplay_HEADERS}
        sdrplaygui.h
    )

    set(TARGET_NAME ${PLUGINS_PREFIX}inputsdrplay)
    set(TARGET_LIB "Qt::Widgets")
    set(TARGET_LIB_GUI "sdrgui")
    set(INSTALL_FOLDER ${INSTALL_PLUGINS_DIR})
else()
    set(TARGET_NAME ${PLUGINSSRV_PREFIX}inputsdrplaysrv)
    set(TARGET_LIB "")
    set(TARGET_LIB_GUI "")
    set(INSTALL_FOLDER ${INSTALL_PLUGINSSRV_DIR})
endif()

if(NOT Qt6_FOUND)
    add_library(${TARGET_NAME} ${sdrplay_SOURCES})
else()
    qt_add_plugin(${TARGET_NAME} CLASS_NAME SDRPlayPlugin ${sdrplay_SOURCES})
endif()

if(NOT BUILD_SHARED_LIBS)
    set_property(GLOBAL APPEND PROPERTY STATIC_PLUGINS_PROPERTY ${TARGET_NAME})
endif()

if(LIBMIRISDR_EXTERNAL)
    add_dependencies(${TARGET_NAME} libmirisdr)
endif(LIBMIRISDR_EXTERNAL)

target_link_libraries(${TARGET_NAME} PRIVATE
        Qt::Core
        ${TARGET_LIB}
	sdrbase
	${TARGET_LIB_GUI}
        swagger
        ${LIBMIRISDR_LIBRARIES}
)

install(TARGETS ${TARGET_NAME} DESTINATION ${INSTALL_FOLDER})

# Install debug symbols
if (WIN32)
    install(FILES $<TARGET_PDB_FILE:${TARGET_NAME}> CONFIGURATIONS Debug RelWithDebInfo DESTINATION ${INSTALL_FOLDER} )
endif()