project(remoteoutput)

set(remoteoutput_SOURCES
	remoteoutput.cpp
	remoteoutputplugin.cpp
    remoteoutputsettings.cpp
    remoteoutputwebapiadapter.cpp
	remoteoutputworker.cpp
    udpsinkfec.cpp
    remoteoutputsender.cpp
    remoteoutputfifo.cpp
)

set(remoteoutput_HEADERS
	remoteoutput.h
	remoteoutputplugin.h
    remoteoutputsettings.h
    remoteoutputwebapiadapter.h
	remoteoutputworker.h
    udpsinkfec.h
    remoteoutputsender.h
    remoteoutputfifo.h
)

include_directories(
    ${CMAKE_SOURCE_DIR}/swagger/sdrangel/code/qt5/client
	${CMAKE_SOURCE_DIR}/devices
    ${CM256CC_INCLUDE_DIR}
    ${Boost_INCLUDE_DIRS}
)

if(NOT SERVER_MODE)
    set(remoteoutput_SOURCES
        ${remoteoutput_SOURCES}
        remoteoutputgui.cpp
        remoteoutputgui.ui
    )
    set(remoteoutput_HEADERS
        ${remoteoutput_HEADERS}
        remoteoutputgui.h
    )
    set(TARGET_NAME ${PLUGINS_PREFIX}outputremote)
    set(TARGET_LIB "Qt::Widgets")
    set(TARGET_LIB_GUI "sdrgui")
    set(INSTALL_FOLDER ${INSTALL_PLUGINS_DIR})
else()
    set(TARGET_NAME ${PLUGINSSRV_PREFIX}outputremotesrv)
    set(TARGET_LIB "")
    set(TARGET_LIB_GUI "")
    set(INSTALL_FOLDER ${INSTALL_PLUGINSSRV_DIR})
endif()

if(NOT Qt6_FOUND)
    add_library(${TARGET_NAME} ${remoteoutput_SOURCES})
else()
    qt_add_plugin(${TARGET_NAME} CLASS_NAME RemoteOutputPlugin ${remoteoutput_SOURCES})
endif()

if(NOT BUILD_SHARED_LIBS)
    set_property(GLOBAL APPEND PROPERTY STATIC_PLUGINS_PROPERTY ${TARGET_NAME})
endif()

if(CM256CC_EXTERNAL)
    add_dependencies(${TARGET_NAME} cm256cc)
endif()

target_link_libraries(${TARGET_NAME} PRIVATE
    Qt::Core
    ${TARGET_LIB}
	sdrbase
	${TARGET_LIB_GUI}
    swagger
    ${CM256CC_LIBRARIES}
)

install(TARGETS ${TARGET_NAME} DESTINATION ${INSTALL_FOLDER})

# Install debug symbols
if (WIN32)
    install(FILES $<TARGET_PDB_FILE:${TARGET_NAME}> CONFIGURATIONS Debug RelWithDebInfo DESTINATION ${INSTALL_FOLDER} )
endif()