0707ad30d1
This commit is primarily changes caused by reviewing "sparse" and "checkpatch" output on our sources, so is somewhat noisy, since things like "printk() -> pr_err()" (or whatever) throughout the codebase tend to get tedious to read. Rather than trying to tease apart precisely which things changed due to which type of code review, this commit includes various cleanups in the code: - sparse: Add declarations in headers for globals. - sparse: Fix __user annotations. - sparse: Using gfp_t consistently instead of int. - sparse: removing functions not actually used. - checkpatch: Clean up printk() warnings by using pr_info(), etc.; also avoid partial-line printks except in bootup code. - checkpatch: Use exposed structs rather than typedefs. - checkpatch: Change some C99 comments to C89 comments. In addition, a couple of minor other changes are rolled in to this commit: - Add support for a "raise" instruction to cause SIGFPE, etc., to be raised. - Remove some compat code that is unnecessary when we fully eliminate some of the deprecated syscalls from the generic syscall ABI. - Update the tile_defconfig to reflect current config contents. Signed-off-by: Chris Metcalf <cmetcalf@tilera.com> Acked-by: Arnd Bergmann <arnd@arndb.de>
99 lines
2.0 KiB
ArmAsm
99 lines
2.0 KiB
ArmAsm
#include <asm-generic/vmlinux.lds.h>
|
|
#include <asm/page.h>
|
|
#include <asm/cache.h>
|
|
#include <asm/thread_info.h>
|
|
#include <hv/hypervisor.h>
|
|
|
|
/* Text loads starting from the supervisor interrupt vector address. */
|
|
#define TEXT_OFFSET MEM_SV_INTRPT
|
|
|
|
OUTPUT_ARCH(tile)
|
|
ENTRY(_start)
|
|
jiffies = jiffies_64;
|
|
|
|
PHDRS
|
|
{
|
|
intrpt1 PT_LOAD ;
|
|
text PT_LOAD ;
|
|
data PT_LOAD ;
|
|
}
|
|
SECTIONS
|
|
{
|
|
/* Text is loaded with a different VA than data; start with text. */
|
|
#undef LOAD_OFFSET
|
|
#define LOAD_OFFSET TEXT_OFFSET
|
|
|
|
/* Interrupt vectors */
|
|
.intrpt1 (LOAD_OFFSET) : AT ( 0 ) /* put at the start of physical memory */
|
|
{
|
|
_text = .;
|
|
_stext = .;
|
|
*(.intrpt1)
|
|
} :intrpt1 =0
|
|
|
|
/* Hypervisor call vectors */
|
|
#include "hvglue.lds"
|
|
|
|
/* Now the real code */
|
|
. = ALIGN(0x20000);
|
|
.text : AT (ADDR(.text) - LOAD_OFFSET) {
|
|
HEAD_TEXT
|
|
SCHED_TEXT
|
|
LOCK_TEXT
|
|
__fix_text_end = .; /* tile-cpack won't rearrange before this */
|
|
TEXT_TEXT
|
|
*(.text.*)
|
|
*(.coldtext*)
|
|
*(.fixup)
|
|
*(.gnu.warning)
|
|
} :text =0
|
|
_etext = .;
|
|
|
|
/* "Init" is divided into two areas with very different virtual addresses. */
|
|
INIT_TEXT_SECTION(PAGE_SIZE)
|
|
|
|
/* Now we skip back to PAGE_OFFSET for the data. */
|
|
. = (. - TEXT_OFFSET + PAGE_OFFSET);
|
|
#undef LOAD_OFFSET
|
|
#define LOAD_OFFSET PAGE_OFFSET
|
|
|
|
. = ALIGN(PAGE_SIZE);
|
|
VMLINUX_SYMBOL(_sinitdata) = .;
|
|
.init.page : AT (ADDR(.init.page) - LOAD_OFFSET) {
|
|
*(.init.page)
|
|
} :data =0
|
|
INIT_DATA_SECTION(16)
|
|
PERCPU(PAGE_SIZE)
|
|
. = ALIGN(PAGE_SIZE);
|
|
VMLINUX_SYMBOL(_einitdata) = .;
|
|
|
|
_sdata = .; /* Start of data section */
|
|
|
|
RO_DATA_SECTION(PAGE_SIZE)
|
|
|
|
/* initially writeable, then read-only */
|
|
. = ALIGN(PAGE_SIZE);
|
|
__w1data_begin = .;
|
|
.w1data : AT(ADDR(.w1data) - LOAD_OFFSET) {
|
|
VMLINUX_SYMBOL(__w1data_begin) = .;
|
|
*(.w1data)
|
|
VMLINUX_SYMBOL(__w1data_end) = .;
|
|
}
|
|
|
|
RW_DATA_SECTION(L2_CACHE_BYTES, PAGE_SIZE, THREAD_SIZE)
|
|
|
|
_edata = .;
|
|
|
|
EXCEPTION_TABLE(L2_CACHE_BYTES)
|
|
NOTES
|
|
|
|
|
|
BSS_SECTION(8, PAGE_SIZE, 1)
|
|
_end = . ;
|
|
|
|
STABS_DEBUG
|
|
DWARF_DEBUG
|
|
|
|
DISCARDS
|
|
}
|