mirror of
https://github.com/saitohirga/WSJT-X.git
synced 2024-08-21 22:06:34 -04:00
Groundwork for calling the decoders directly from C/C++ threads. To access the timer module timer_module must now be used. Instrumented code need only use the module function 'timer' which is now a procedure pointer that is guaranteed to be associated (unless null() is assigned to it, which should not be done). The default behaviour of 'timer' is to do nothing. If a Fortran program wishes to profile code it should now use the timer_impl module which contains a default timer implementation. The main program should call 'init_timer([filename])' before using 'timer' or calling routines that are instrumented. If 'init_timer([filename])'. If it is called then an optional file name may be provided with 'timer.out' being used as a default. The procedure 'fini_timer()' may be called to close the file. The default timer implementation is thread safe if used with OpenMP multi-threaded code so long as the OpenMP thread team is given the copyin(/timer_private/) attribute for correct operation. The common block /timer_private/ should be included for OpenMP use by including the file 'timer_common.inc'. The module 'lib/timer_C_wrapper.f90' provides a Fortran wrapper along with 'init' and 'fini' subroutines which allow a C/C++ application to call timer instrumented Fortran code and for it to receive callbacks of 'timer()' subroutine invocations. No C/C++ timer implementation is provided at this stage. git-svn-id: svn+ssh://svn.code.sf.net/p/wsjt/wsjt/branches/wsjtx@6320 ab8295b8-cf94-4d9e-aec4-7959e3be5d79
58 lines
1.7 KiB
Fortran
58 lines
1.7 KiB
Fortran
module timer_c_wrapper
|
|
use :: iso_c_binding, only: c_ptr
|
|
use timer_module, only: timer, null_timer
|
|
implicit none
|
|
|
|
!
|
|
! C interoperable callback setup
|
|
!
|
|
abstract interface
|
|
subroutine c_timer_callback (context, dname, k)
|
|
use, intrinsic :: iso_c_binding, only: c_ptr, c_char
|
|
implicit none
|
|
type(c_ptr), value, intent(in) :: context
|
|
character(c_char), intent(in) :: dname(*)
|
|
integer, intent(in), value :: k
|
|
end subroutine c_timer_callback
|
|
end interface
|
|
|
|
public :: init, fini
|
|
|
|
private
|
|
|
|
!
|
|
! the following are singleton items which assumes that any timer
|
|
! implementation should only assume one global instance, probably a
|
|
! struct or class object whose address is stored the context below
|
|
!
|
|
type(c_ptr), private :: the_context
|
|
procedure(C_timer_callback), pointer, private :: the_callback
|
|
|
|
contains
|
|
subroutine timer_callback_wrapper (dname, k)
|
|
use, intrinsic :: iso_c_binding, only: c_null_char
|
|
implicit none
|
|
character(len=8), intent(in) :: dname
|
|
integer, intent(in) :: k
|
|
call the_callback (the_context, trim (dname) // c_null_char, k)
|
|
end subroutine timer_callback_wrapper
|
|
|
|
subroutine init (context, callback)
|
|
use, intrinsic :: iso_c_binding, only: c_ptr, c_funptr, c_f_procpointer
|
|
use iso_c_utilities, only: c_to_f_string
|
|
use timer_module, only: timer
|
|
implicit none
|
|
type(c_ptr), value, intent(in) :: context
|
|
type(c_funptr), value, intent(in) :: callback
|
|
the_context=context
|
|
call c_f_procpointer (callback, the_callback)
|
|
timer => timer_callback_wrapper
|
|
end subroutine init
|
|
|
|
subroutine fini ()
|
|
implicit none
|
|
timer => null_timer
|
|
end subroutine fini
|
|
|
|
end module timer_c_wrapper
|